**L’optique médicale dans le SNDS**

Dans le SNDS, les dépenses en optique sont regroupées sous les codes prestations ci-dessous (variable PRS\_NAT\_REF):

3523, 3524, 3525, 3526, 3527, 3528, 3529, 3530, 3531, 3532, 3533, 3534, 3535, 3536, 3537, 3538, 3539, 3553, 3554, 3555, 3556, 3557, 3581, 3582, 3583, 5101, 5102, 5103, 5104, 5105, 5106, 5107

Le détail de ces prestations est donné par le code LPP. Le libellé des codes LPP donne les caractéristiques de verres :

- Adultes ou enfants

- Verre blanc ou teinté

- Unifocal ou multifocal

- Sphériques ou sphéro-cylindriques ainsi que l'intensité de cette correction

On trouve les codes LPP dans la variable TIP\_PRS\_IDE dans la table de prestation affinée des dispositifs médicaux : [ER\_TIP\_F](../tables/DCIR/ER\_TIP\_F.md).

Il faut donc effectuer une jointure entre la table prestation ER\_PRS\_F et ER\_TIP\_F pour avoir le détail par codes LPP

**Exemple de code pour extraire toutes les dépenses d’optique médicale d’une année :**

%macro Tables\_MENSUELLES (indice, ddmmaaaa\_flux, annee);

PROC SQL;

CREATE TABLE base\_opt&indice. AS SELECT

 t1.BEN\_NIR\_PSA,

 t1.BEN\_RNG\_GEM,

 t1.EXE\_SOI\_AMD,

 t1.PRS\_ACT\_QTE,

 t1.BEN\_NAI\_ANN,

 t1.BEN\_CMU\_TOP,

 t1.BEN\_CMU\_ORG,

 t1.BSE\_REM\_BSE,

 t1.BSE\_REM\_MNT,

 t1.EXE\_SOI\_DTD,

 t1.PRS\_PAI\_MNT,

 t1.PRS\_NAT\_REF,

 t1.RGO\_REM\_TAU,

 t1.pfs\_exe\_num,

 t2.TIP\_PRS\_IDE,

 t2.tip\_ord\_num,

 t2.TIP\_ACT\_QSN

FROM ORAVUE.ER\_PRS\_F AS t1 INNER JOIN ORAVUE.ER\_TIP\_F AS t2

ON (t1.DCT\_ORD\_NUM = t2.DCT\_ORD\_NUM AND t1.FLX\_DIS\_DTD = t2.FLX\_DIS\_DTD AND

 t1.FLX\_EMT\_NUM = t2.FLX\_EMT\_NUM AND t1.FLX\_EMT\_ORD = t2.FLX\_EMT\_ORD AND t1.FLX\_EMT\_TYP = t2.FLX\_EMT\_TYP AND t1.FLX\_TRT\_DTD = t2.FLX\_TRT\_DTD AND t1.ORG\_CLE\_NUM = t2.ORG\_CLE\_NUM AND t1.PRS\_ORD\_NUM = t2.PRS\_ORD\_NUM AND t1.REM\_TYP\_AFF = t2.REM\_TYP\_AFF)

WHERE t1.exe\_soi\_amd LIKE '&annee.%'

 AND t1.FLX\_DIS\_DTD = DHMS(mdy(input(substr(put(&ddmmaaaa\_flux.,8.),3,2),2.),input(substr(put(&ddmmaaaa\_flux.,8.),1,2),2.),input(substr(put(&ddmmaaaa\_flux.,8.),5,4),4.)),0,0,0)

 AND t1.DPN\_QLF ne 71 and t1.PRS\_DPN\_QLP ne 71

 AND t1.PRS\_NAT\_REF in (3523,3524,3525,3526,3527,3528,3529,3530,3531,3532,3533,3534,3535,3536,3537,3538,3539,3553,3554,3555,3556,3557,3581,3582,

 3583,5101,5102,5103,5104,5105,5106,5107)

 AND t2.TIP\_PRS\_IDE in (2200393,2261874,2206800,2238941,2242457,2243304,2243540,2245036,2268385,2270413,2283953,2273854,2297441,2248320,2219381,2291088,

 2203240,2259966,2212976,2226412,2235776,2252668,2254868,2263459,2280660,2282793,2284527,2287916,2288519,2265330,2295896,2299523,2234239,2238792,2240671,2259245,

 2264045,2282221,2202452,2259660,2290396,2227038,2202239,2245384,2252042,2291183,2295198,2299180,2210546,2223342,2200795,2222408,2227908,2227920,2246716,2247905,

 2269025,2274109,2287862,2293957,2204066,2278219,2202305,2232855,2238958,2247934,2256790,2266676,2267397,2285136,2289571,2292030,2295815,2297866,2297926,2251545)

;

QUIT;

%mend;

OPTIONS MPRINT;

%MACRO boucle (annee) ;

%let anb=%eval(&annee+1);

/\* Flux de soins remontés en 2015 pour les soins de l'année 2015 \*/

%do i = 2 %to 12 ;

 data \_null\_; call symput ('j',put(%eval(&i),z2.));run;

 %Tables\_MENSUELLES(&annee.&i.,01&j.&annee.,&annee.) ;

%end ;

/\* Flux de soins remontés en 2016 pour les soins de l'année 2015: 6 mois de remontée de flux après décembre 2015\*/

%do i = 1 %to 6 ;

 data \_null\_; call symput ('j',put(%eval(&i),z2.));run;

 %Tables\_MENSUELLES(&anb.&i.,01&j.&anb.,&annee.) ;

%end ;

%MEND ;

%boucle(2015);

/\*On crée la table annuelle à partir des tables mensuelles\*/

%MACRO crea\_table;

 DATA libopttb.extraction\_optique\_2015;

 SET

 %DO annee=2015 %TO 2016;

 %if &annee = 2016 %then %do;

 %DO i= 1 %TO 6; base\_opt&&annee.&i. %END;

 %END;

 %else %do;

 %DO i= 2 %TO 12; base\_opt&&annee.&i. %END;

 %END;

 %END;

 ;

 RUN;

%MEND;

%crea\_table;

/\*Marché de l'optique remboursable en 2015 : 5 842 721 868€\*/

PROC SQL;

 CREATE TABLE dep\_totale\_2015 AS

 SELECT sum(prs\_pai\_mnt)

 FROM libopttb.extraction\_optique\_2015

 WHERE tip\_ord\_num=1

 ;

QUIT;

Le programme est conçu pour être utilisé sur le DCIR. Les tables du DCIR se trouvent dans la bibliothèque ORAVUE.

Dans le DCIR, les données sont partitionnées via la date de remontée de flux (FLX\_DIS\_DTD). Pour optimiser le temps de traitement, il est nécessaire de créer un filtre sur cette variable lorsqu’on effectue une requête. Il est fortement recommandé d’extraire les données mensuellement et de les fusionner ensuite pour créer une table annuelle ou pluriannuelle. Pour cela, nous proposons le macro-programme Tables\_MENSUELLES. Le macro-programme a trois arguments : un indice (donnant le nom des différentes tables créées), la date de remontée de flux et l’année en date de soins.

Ainsi, Tables\_MENSUELLES crée 17 tables qui correspondent à 11 mois de remontée de flux en 2015 et 6 mois de remontée de flux en 2016.

Afin d’extraire toutes les dépenses d’optique médicale de l’année 2015, nous utilisons les codes LPP. Ces codes sont donnés par la variable TIP\_PRS\_IDE dans la table de prestation affinée des dispositifs médicaux : ER\_TIP\_F. Le libellé des codes LPP donne les caractéristiques de verres :

* Adultes ou enfants
* Verre blanc ou teinté
* Unifocal ou multifocal
* Sphériques ou sphéro-cylindriques ainsi que l’intensité de cette correction

Lorsque tip\_ord\_num est supérieur à 1, cela signifie que pour une ligne de la table prestation, on a n lignes sur la table affinée. Il faut donc être prudent car les infos de la table prestations ont été dupliquées sur ces lignes. Ci-dessous un exemple dans le DCIRS (En violet, les données de la table prestation, en orange les données de la table affinées) :



Pour un même acte (même bénéficiaire, même professionnel de santé et une même date de soins) et une même prestation (3533 ici), on a un code LPP (TIP\_PRS\_IDE) différent avec une base de remboursement différente (TIP\_ACT\_PRU) ce qui donne lieu à une ligne supplémentaire sur la table affinée. La variable de numéro séquentiel (TIP\_SEQ\_NUM ici, TIP\_ORD\_NUM dans le DCIR) indique le nombre de lignes dans la table affinée pour un acte. Les informations de la ligne unique de la table prestation ont été dupliquées lors de la jointure, notamment le montant total (prs\_pai\_mnt) de 400,8€.